Списание суммы дооценки основных средств

Всем привет! Я давно не давал о себе знать. Поэтому спешу сообщить, что я жив-здоров, чего и вам желаю. Но я здесь не для того, чтобы только поздороваться. Есть реальная тема.

Речь пойдёт об основных средствах. А если точнее - о переоценке основных средств. Однажды я уже затрагивал тему переоценки в статье «Как программно создать и заполнить документ «Корректировка записей регистров», где в качестве примера я рассматривал переоценку основных средств. Вспомним, что увеличение стоимости основных средств и накопленной амортизации отражается следующими проводками:

• Дт. 01.01 - Кт. 83.01 - Увеличение первоначальной стоимости ОС.
• Дт. 83.01 - Кт. 02.01 - Увеличение суммы накопленной амортизации ОС.

При списании основного средства, согласно ПБУ 6/01, сумма дооценки (остаток на счете 83.01) основного средства должна быть включена в состав нераспределенной прибыли:

• Дт. 83.01 - Кт. 84.01 - Включение суммы дооценки в состав нераспределенной прибыли.

Раньше в конфигурации "Бухгалтерский учёт" на платформе 7.7 документы "Передача ОС" и "Списание ОС" формировали последнюю проводку автоматически. А вот в новых конфигурациях "Управление производственным предприятием", "Бухгалтерия предприятия" на 8-ой платформе 1С аналогичные документы такую проводку не формируют. Почему так, в чём причина, мне не известно. Но ПБУ 6/01 никто не отменял - сумма дооценки должна быть списана со счета 83.01. Надо менять конфигурацию. А теперь давайте вспомним, как правильно вносить изменения в типовые конфигурации, чтобы потом не было мучительно больно при обновлении релизов. В данном случае мы можем использовать возможности подписок на события. Типовые документы останутся в первозданном виде.

Создайте новый общий модуль и поместите в него экспортную процедуру:

Процедура ПриПроведенииСписаниеПередачаОС(Источник, Отказ, РежимПроведения) Экспорт
    Сч83_01 = ПланыСчетов.Хозрасчетный.ПриростСтоимостиИмуществаПоПереоценке;
    Сч84_01 = ПланыСчетов.Хозрасчетный.ПрибыльПодлежащаяРаспределению;
    СписокОС = Новый СписокЗначений;
    СписокОС.ЗагрузитьЗначения(Источник.ОС.ВыгрузитьКолонку("ОсновноеСредство"));
 
    Запрос = Новый Запрос;
    Запрос.Текст = 
    "ВЫБРАТЬ
    | ХозрасчетныйОстатки.Субконто1 КАК ОсновноеСредство,
    | ХозрасчетныйОстатки.СуммаОстатокКт КАК СуммаДооценки
    |ИЗ
    | РегистрБухгалтерии.Хозрасчетный.Остатки(
    |   &ДатаОстатков,
    |   Счет = &Сч83_01,
    |   ,
    |   Организация = &Организация
    |    И Субконто1 В (&СписокОС)) КАК ХозрасчетныйОстатки";
    Запрос.УстановитьПараметр("ДатаОстатков", Источник.Дата);
    Запрос.УстановитьПараметр("Организация" , Источник.Организация);
    Запрос.УстановитьПараметр("СписокОС", СписокОС);
    Запрос.УстановитьПараметр("Сч83_01", Сч83_01);
    ТЗДооценкаОС = Запрос.Выполнить().Выгрузить(); 
    Если ТЗДооценкаОС.Количество() > 0 Тогда
        ПроводкиБУ = Источник.Движения.Хозрасчетный;
        Для каждого СтрокаДооценка Из ТЗДооценкаОС Цикл
            Проводка = ПроводкиБУ.Добавить();
            Проводка.Период       = Источник.Дата;
            Проводка.Организация  = Источник.Организация;
            Проводка.Содержание   = "Сумма дооценки включена в состав нераспр. прибыли";
            Проводка.Сумма        = СтрокаДооценка.СуммаДооценки;
            Проводка.СчетДт = Сч83_01;
            БухгалтерскийУчет.УстановитьСубконто(Проводка.СчетДт, Проводка.СубконтоДт, "ОсновныеСредства", СтрокаДооценка.ОсновноеСредство);
            Проводка.СчетКт = Сч84_01;
        КонецЦикла;
        ПроводкиБУ.Записать();
    КонецЕсли;
КонецПроцедуры

Теперь создайте новую подписку на событие. Назовите её, скажем, ОбработкаПроведенияСписаниеПередачаОС. В качестве источников укажите документы "Списание ОС" и "Передача ОС", в качестве события - ОбработкаПроведения, а в качестве обработчика - созданную процедуру ПриПроведенииСписаниеПередачаОС.

Как это работает. При проведении документа, тип которого указан в качестве источника в подписке, сначала будет выполнена процедура ОбработкаПроведения самого документа. Затем управление будет передано обработчику подписки, то есть процедуре ПриПроведенииСписаниеПередачаОС. Дополнительная проводка Дт. 83.01 - Кт. 84.01 будет дописана к проводкам документа.
P. S. Пример сделан для конфигурации "Бухгалтерия предприятия".